ORA4MAS (Moise platform based on artifacts)

/*
  (Traditional) Writing paper example

  to be run as a JaCaMo application

  by Jomi (2010)
*/

mas wp {

    agent bob
    agent alice
    agent carol

}

// This agent creates the group/scheme to write a paper
// and adopts the role "editor" in the group

my_role(editor).

{ include("common.asl") }

/* Initial goals */

!create.

/* Plans */

+!create
  <- .my_name(Me);
     createWorkspace(ora4mas);
     joinWorkspace(ora4mas,O4MWsp);

     makeArtifact(myorg, "ora4mas.nopl.OrgBoard", ["../wp-os.xml"], OrgArtId)[wid(O4MWsp)];
     focus(OrgArtId);

     createGroup("mypaper", wpgroup, GrArtId);
     debug(inspector_gui(on))[artifact_id(GrArtId)];
     setOwner(Me);

     .print("group created");

     // wait for alice
     ?play(alice,writer,mypaper);

     // wait for carol
     ?play(carol,writer,mypaper);

     !run_scheme(sch1).

//+group(_,_,AID)  <- focus(AID).
//+scheme(_,_,AID) <- focus(AID).

// general error handler for goal start
-!start[error(I),error_msg(M)] <- .print("failure in starting! ",I,": ",M).

+!run_scheme(S)
   <- createScheme(S, writePaperSch, SchArtId);
      debug(inspector_gui(on))[artifact_id(SchArtId)];
      .print("scheme ",S," created");
      addScheme(S)[artifact_name("mypaper")];
      .print("scheme is linked to responsible group");
      commitMission(mManager)[artifact_id(SchArtId)].
-!run_scheme(S)[error(I),error_msg(M)] <- .print("failure creating scheme ",S," -- ",I,": ",M).

// application domain goals
+!wtitle     <- .wait(500); .print("writing title...").
+!wabs       <- .print("writing abstract...").
+!wsectitles <- .print("writing section title...").
+!wconc	     <- .print("writing conclusion...").
+!wp         <- .print("paper finished!").

+goalState(sch1, wp, _, _, satisfied)
   <- .wait(1000);
      destroyScheme(sch1);
      .print("starting a new scheme...");
      !!run_scheme(sch2).

+?play(A,R,G) <- .wait({+play(_,_,_)},100,_); ?play(A,R,G).

// signals
+normFailure(N)  <- .print("norm failure event: ", N).
+destroyed(Art)  <- .print("Artifact ",Art," destroyed").

// for debug (prints out the new states of goals)
//+goalState(Sch,Goal,CommittedAgs,AchievedBy,State)
//   <- .print("                         goal changed: ", goalState(Sch,Goal,CommittedAgs,AchievedBy,State)).

{ include("$jacamoJar/templates/common-moise.asl") }
{ include("$jacamoJar/templates/org-obedient.asl") }

/* Initial goals */

!play.
!join.

/* Plans */

+!play
   <- lookupArtifact("mypaper",GrId);
      ?my_role(R);
      adoptRole(R)[artifact_id(GrId)];
      focus(GrId).
-!play
   <- //.print("waiting to play a role");
      .wait(100);
      !play.

+!join : joined("ora4mas",_).
+!join
   <- joinWorkspace("/main/ora4mas",_).
-!join
   <- .print("waiting to join ora4mas");
      .wait(200);
      !join.

+!quit_mission(M,S)
   <- .print("leaving my mission ",M," on ",S,"....");
      leaveMission(M)[artifact_name(S)].

// this agent waits for the group creation and then
// adopts the role writer and
// commits to the missions mColaborator and mBib

my_role(writer).

{ include("common.asl") }

/* Plans */

// application domain goals
+!wsecs <- .print("writing sections...").
+!wrefs <- .print("organising bibliography...").

// conditions to leave missions
@lgss1[atomic]
+goalState(Scheme,wsecs,_,_,satisfied)
    : .my_name(Me) & commitment(Me,mColaborator,Scheme)
   <- !quit_mission(mColaborator,Scheme).

@lgss2[atomic]
+goalState(Scheme,wrefs,_,_,satisfied)
    : .my_name(Me) & commitment(Me,mBib,Scheme)
   <- !quit_mission(mBib,Scheme).

{ include("$jacamoJar/templates/common-moise.asl") }
{ include("$jacamoJar/templates/org-obedient.asl") }

// this agent waits for the group creation and then
// adopts the role writer and
// commits to the mission mColaborator

my_role(writer).

{ include("common.asl") }

/* Plans */

// application domain goals
+!wsecs[scheme(S)]
   <- .print("writing sections for scheme ",S,"...").

// when my goal in the scheme is satisfied, leave my mission
@lqm[atomic]
+goalState(Scheme,wsecs,_,_,satisfied)
    : .my_name(Me) & commitment(Me,mColaborator,Scheme)
   <- !quit_mission(mColaborator, Scheme).


// plans to handle obligations

// only commits to mColaborator!
+obligation(Ag,Norm,committed(Ag,mColaborator,Scheme),Deadline)[artifact_id(ArtId),workspace(_,_,W)]
    : .my_name(Ag)
   <- .print("I am obliged to commit to mColaborator on ",Scheme,"... doing so");
      commitMission(mColaborator)[artifact_name(Scheme), wid(W)].
+obligation(Ag,Norm,committed(Ag,Mission,Scheme),Deadline)
    : .my_name(Ag)
   <- .print("Ignoring obligation to commit to ",Mission," on ",Scheme).

{ include("$jacamoJar/templates/common-moise.asl") }
{ include("$jacamoJar/templates/org-obedient.asl") }